Shader "Zekk/ScreenSpaceDots"
{
    Properties
    {
        [HDR]_Col1 ("Color 1", color) = (1,1,1,1)
        _DotDensity ("Dot Density", float) = 54.7
        _DotSize ("Dot Size", range(0,.5)) = .2
        _EdgeFade ("Edge Fade", range(0, 1)) = .1
    }
    SubShader
    {
        Tags { "RenderType"="tranparent" "queue"="Transparent" }
        zwrite Off
        ztest lequal
        blend srcalpha oneminussrcalpha

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                UNITY_VERTEX_INPUT_INSTANCE_ID
                float4 vertex : POSITION;
            };

            struct v2f
            {
                UNITY_VERTEX_OUTPUT_STEREO
                float4 vertex : SV_POSITION;
                float4 screenPos : TEXCOORD1;
            };

            float4 _Col1;
            float _DotDensity;
            float _DotSize;
            float _EdgeFade;

            v2f vert (appdata v)
            {
                v2f o;
                UNITY_SETUP_INSTANCE_ID( v );
                UNITY_INITIALIZE_OUTPUT( v2f, o );
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO( o );
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.screenPos = ComputeScreenPos(o.vertex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                UNITY_SETUP_STEREO_EYE_INDEX_POST_VERTEX( i );
                float screenDim = _ScreenParams.x / _ScreenParams.y;
                float2 SSP = ((((i.screenPos.xy/i.screenPos.w).xy)*2-1) * float2(screenDim,1));
                float4 col = smoothstep(0,-_EdgeFade,length(frac((SSP)*_DotDensity)-.5)-_DotSize);
                return _Col1*col;
            }
            ENDCG
        }
    }
}
